How do you wait for an exe to complete in batch file?

Question

I'm trying to create a script to execute an exe on shutdown in order to install sp1. my script goes something like (not actual bat script).

If installed GOTO END
    Install.exe
END:

My problem is that when it runs, it starts the installer, then finishes the script because the installer's a different process and follows up by shutting down the install process because the computer's shutting down and shutting down the system (at least, that's what i think it's doing.)

Is there any way to tell it to wait until the process it started completes and then shutdown?

score 105 · Accepted Answer · answered Mar 09 '11 at 20:54

105

Try running

START /WAIT Install.exe

answered Mar 09 '11 at 20:54

Bart De Vos

17,761
6
62
81

great job with this answer! – Alex Gordon Oct 17 '12 at 20:33
Can you chain? `like start /wait install; exit`? – Serj Sagan Jul 11 '16 at 22:03
you can always do `cmd /C start /wait install` – graywolf Aug 18 '16 at 12:02
What if you need to wait for a process that the batch file didn't start? – Kyle Delaney Apr 30 '18 at 15:48
2

doesn't work for me... Trying to invoke MSBuild (which takes like 2 min), and this returns immediately. How to debug this? – Gulzar Jun 22 '20 at 09:41

npocmaka · Answer 2 · 2022-05-10T09:44:57.837

29

One shorter way:

Install.exe|more

Also

install|rem

could be used , though with more eventually you'll be able to catch some console output. And this is the reason it works - the piped command waits for input until the .exe is finished.

Update

For windows 8 and 10 there's a new tool coming with windows called scriptrunner which also can be used for this purpose:

ScriptRunner.exe -appvscript Install.exe -appvscriptrunnerparameters -wait

edited May 10 '22 at 09:44

answered Oct 22 '15 at 12:34

npocmaka

421
5
6

what if the exe takes parameters? how would that work? – m4l490n Feb 04 '19 at 20:22
@m4l490n - it will work ok. The redirection and conditional execution operators have the higher priority in the batch scripts (`<`,`>`,`>>`,`&`,`&&`,`||`,`|`) – npocmaka Feb 05 '19 at 09:11
Also, Try `CALL Install.exe` – Babak Oct 09 '20 at 18:36

score 17 · Answer 3 · answered Mar 09 '11 at 21:25

17

Either calling the exe directly from the batch file, or using start /wait will work but there is a caveat.

If the exe you call then creates other process, such as calling another exe, and then exits the batch file will continue processing after the called exe has terminated, as it has no knowledge of other processes started by it.

In your case this is a real problem because installers normally extract files from some form of compressed container, which may be embedded in the exe itself, then fire off one of the extracted files and exit. Some installers provide command line parameters which tell the original exe not to exit until the entire installation is complete, so that's something you may want to investigate. Other than that, there's no real way around this with batch files alone and would take a programmatic solution to solve.

answered Mar 09 '11 at 21:25

John Gardeniers

27,262
12
53
108

You could always add a loop to the shutdown routine to check to see if msiexec.exe (or whatever the hell it is) is running and then wait and loop again. – mfinni Mar 09 '11 at 22:02
@mfinni, just to complicate matters even further, `msiexec` often fires off other processes as well. :( – John Gardeniers Mar 10 '11 at 01:31
1

Actually, why do you need `start /wait` at all? I myself believed it's needed to use `start /wait` to block batch file until GUI (as opposite to a console) application finishes. But testing it now, I see that batch files actually wait even for GUI applications. I have posted corresponding question: [Why GUI application blocks a batch file?](http://stackoverflow.com/questions/19381082/why-gui-application-blocks-a-batch-file) – Martin Prikryl Oct 15 '13 at 18:28
I had this problem, added my solution as an answer. – FreeSoftwareServers Mar 15 '18 at 02:19

Rachit Kumar · Answer 4 · 2014-06-19T13:32:15.297

6

Here is an example using MATLAB! I have assumed that the path setup for MATLAB is done and MATLAB exit is being ensured by the FileName.m file (or user has specified it internally).

echo off
matlab -nosplash /r "FileName.m"
:loop
tasklist /fi "imagename eq MATLAB.exe" |find ":" > nul
if errorlevel 1 goto loop
exit

edited Jun 19 '14 at 13:32

answered Jun 19 '14 at 12:46

Rachit Kumar

69
1
2

2

Assuming Matlab seems a bit strange to me, especially here on serverfault. – Erik Jun 19 '14 at 12:55
This can work for things other than MATLAB. Just change "MATLAB.exe" to something else. And perhaps fix that second 'find' to search for the exe again in the filtered output. – Oliver Bock Jul 18 '14 at 06:17

score 2 · Answer 5 · answered Mar 15 '18 at 02:21

I had the problem @John Gardeniers Had or described, where my exe called another exe and terminated, therefor start /wait didn't work. I created a "while loop" to check if its running and then move on once its done. The times can be tweaked to suit your needs.

TIMEOUT /T 60

SETLOCAL EnableExtensions
set EXE=MYEXETOCHECK.exe
:LOOPSTART
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto FOUND
goto FIN
:FOUND
TIMEOUT /T 30
goto LOOPSTART
:FIN

score 1 · Answer 6 · edited Aug 28 '20 at 17:50

Similar to @FreeSoftwareServers file, I needed to wait for a program to start that wasn't started by the batch file. Then wait several seconds to start a program that hooks onto the program I'm checking for. If you want the file to timeout after checking a certain amount of times, you could use a counter within the loop to limit the amount of times it loops.

SETLOCAL EnableExtensions
set EXE=MYEXETOCHECK.exe
:LOOPSTART
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto FOUND
TIMEOUT /T 3
goto LOOPSTART
:FOUND
TIMEOUT /T 15
START HOOKINGPROGRAM.exe

The first TIMEOUT determines how often the loop will repeat, searching for the program. This can be modified to fit your needs.

score 0 · Answer 7 · answered Mar 09 '11 at 21:03

You can use the the start /wait command. This starts an application and waits for it to end.

Or if you know how long it takes to execute, you can take a look at the sleep command, provided by the Windows Server 2003 Resource Kit Tools . Sleep.exe can be used to pause your batch for any number of seconds to allow the program to install fully before the batch file proceeds to install anything else. There are some programs which ignore the "start /wait" syntax, due to the program itself launching another process, then the sleep.exe is very useful.

How do you wait for an exe to complete in batch file?

7 Answers7