The current year is 2018 and I continue to deal with this problem – because I’m greedy and I want to eat the cake and to keep it. Namely, I want to continue to use Windows 8.1 and keep the Windows 10 upgrade offer available – without the nagging window permanently cluttering my desktop.
I have solved it with an AutoHotkey script. It captures the unwanted window (either when it pops up or instantly, if it’s present already) and automatically minimizes it to tray. You can double click it later at any time to show the window again or to hide it again. (You can modify this solution to work for any window, not only Windows upgrade.) Here’s how it looks:
![Windows 10 upgrade popup killer](../../I/static/images/994d5be2c26458a8ff7b18aba9809bae304342eaa2ef039743c327b364017d37.png)
Install AutoHotkey, save the following script to your start-up folder – and you can forget about the Windows upgrade for as long as you want without cancelling it. This way you can eat your cake and keep it. You only need to edit appWinTitle
and appWinText
to reflect your Windows language.
; win10killer.ahk
; Minimise Windows 10 upgrade notice to tray.
;
; Based on:
; https://autohotkey.com/board/topic/124024-minimize-to-tray/
; https://www.reddit.com/r/AutoHotkey/comments/33djss/help_minimize_to_tray/
; 2018-02-01
#Persistent
appPath = C:\Windows\System32\wuauclt.exe
appWinTitle = Windows Update ahk_exe wuauclt.exe ; Change this to your language.
appWinText = Start the upgrade now ; Change this to your language.
appName = Windows 10 upgrade notice ; Arbitrary description.
hwnd =
ModifyAutohotkeyTrayIconAndMenu()
CaptureWindowAndMinimizeToTray()
WinWaitClose ahk_id %hwnd% ; Intended to wait forever.
MsgBox,,, %appName% was closed. Quitting script., 1 ; Should never happen.
ExitApp ; Should never happen.
TrayClick:
OnTrayClick()
return
ModifyAutohotkeyTrayIconAndMenu() {
global appPath, appName
Menu Tray, Icon, %appPath% ; Borrow icon from the upgrade executable.
Menu Tray, Add, Show/hide %appName%, TrayClick
Menu Tray, Default, Show/hide %appName%
}
CaptureWindowAndMinimizeToTray() {
global hwnd
global appPath, appWinTitle, appWinText
DetectHiddenWindows On
WinWait,, %appWinText% ; or: WinWait, %appWinTitle%
hwnd := WinExist()
WinHide ahk_id %hwnd%
}
OnTrayClick() { ; Show/hide target window on double click
global hwnd
if DllCall("IsWindowVisible", "Ptr", hwnd)
WinHide ahk_id %hwnd%
else {
WinShow ahk_id %hwnd%
WinActivate ahk_id %hwnd%
}
}
Keywords to help people find this page: “Windows Upgrade | Your upgrade is ready to install | Save your work and leave your PC plugged in and turned on. The upgrade might take a while, but we’ll let you know when it’s done. | Schedule it for later / Start the upgrade now.”
there is a full step by step guide here: http://www.howtogeek.com/218856/how-do-you-disable-the-get-windows-10-icon-shown-in-the-notification-tray/
– Divin3 – 2015-07-31T03:21:15.740@Divin3 I have no issue with the icon. I want to close the window that it opens. – TreeTree – 2015-07-31T03:24:12.743
1that is included in the guide: Removing KB3035583 should do the trick – Divin3 – 2015-07-31T03:24:51.840
if following the guide doesn't help, just leave a comment, and I will do some more research. – Divin3 – 2015-07-31T03:39:01.890
@Divin3 KB3035583 doesn't show up in the list. How do I find out which one I need to delete? (Might be because I'm not in the US?) – PandaConda – 2015-08-24T16:27:19.453
Nevermind, found it. – PandaConda – 2015-08-24T16:37:49.953
@PandaConda - I am glad You found it. If You have any questions, feel confident to ask. – Divin3 – 2015-08-24T17:35:55.977