Can't run batch file in Server 2012

Question

This site rocks! I am trying to run a simple .bat file on Server 2012 that will ping another server, filter out all the lines except one, and then write to a file for later use (I then want that file sent somewhere, but that is a project for another discussion!).

I have pieced together some commands from searching this forum, and have the commands needed to make this happen. When I run these commands one at a time from ms-dos, it works. However, when it stick them all into a bat file something gets messed up. I don't have much experience with Server os's, so it could be something simple I am missing. Any help would be appreciated.

Here are my instructions

ping 10.18.89.154 >C:\pinglog.txt
FOR /F "skip=8 delims=" %i in (C:\pinglog.txt) do @echo %i >C:\TEMP.TXT
SET /P SHOW= < C:\TEMP.TXT
ECHO %SHOW% >C:\pinglog.txt

And here is the result when run manually:

Packets: Sent = 4, Received = 4, Lost = 0 (0% loss),

But when I run those commands in a batch file, the cmd window hangs on the first line, shows the below text in the cmd window and produces a blank file...

C:\Users\administrator.WSI\Documents>ping 10.18.89.154 1>C:\pinglog.txt

Any Thoughts?

Answer 1

Can't run batch file in Server 2012

Here is a much simpler way to do what you want (in a one line command):

ping 10.18.89.154 | findstr "Packets" > c:\pinglog.txt

The above command will work as is from the command line or from a batch file.

The following batch file uses google.com as the ping target as I can't ping something on your network with a private IP address.

test.cmd:

ping www.google.com | findstr "Packets" > pinglog.txt

example output:

C:\test>test

C:\test>ping www.google.com   | findstr "Packets"  1>pinglog.txt

C:\test>type pinglog.txt
    Packets: Sent = 4, Received = 4, Lost = 0 (0% loss),

C:\test>

---

To use your original commands, in the for /f command you need to replace % with %%:

FOR /F "skip=8 delims=" %%i in (C:\pinglog.txt) do @echo %%i >C:\TEMP.TXT

---

Is there a way to isolate the values in that line, or can you only produce the entire line?

The reason I wanted to bring back the the "received" value only, is if that file is "0" I could trigger an alert based on that.

The following batch file will find the value of "Received" and will output "Ping failed" if that value is 0, otherwise it will output nothing.

As a bonus it doesn't use any files.

You can replace echo "Ping failed" with your alert command when you decide what this should be.

test.cmd:

@echo off
for /f "usebackq skip=8 tokens=7" %%i in (`ping 10.18.89.154`) do (
   set _result=%%i
   goto :done
   )
:done
if "%_result:~0,1%"=="0" echo "Ping failed"

---

Further reading

• FOR /F

%%parameter A replaceable parameter: in a batch file use %%G (on the command line %G)

Answer 2

I had the same problem described in the original question. I found no answers. I finally resolved the issue by creating a shortcut to the batch file. When launching the batch file from a shortcut, the file executes as expected. Otherwise, it hangs on the first line.