Emailing folder's content through AppleScript

Question

I'm trying to write an AppleScript that e-mails all files of the specified folder. It works as expected when there is only one file but doesn't when there are more than one. It just gives me this error:

"Mail got an error: Can’t make {alias \"Macintosh HD:Users:me:temp_photos:IMG_2902.JPG\", alias \"Macintosh HD:Users:me:temp_photos:IMG_2903.JPG\"} into type file." number -1700 from {alias "Macintosh HD:Users:me:temp_photos:IMG_2902.JPG", alias "Macintosh HD:Users:me:temp_photos:IMG_2903.JPG"} to file

Here is my AppleScript

    tell application "Finder"
    set attchList to (every item of TempPhotos) as alias list
end tell

set theSender to "Me<[e-mail]>"
set recipName to "You"
set recipAddress to "[e-mail]"

tell application "Mail"

    set newmessage to make new outgoing message with properties {subject:"Important File Attachment", content:msgText & return & return, visible:false}
    tell newmessage
        set visible to false
        set sender to theSender
        make new to recipient with properties {name:recipName, address:recipAddress}
        make new attachment with properties {file name:attchList} at after the last paragraph

    end tell
    send newmessage
end tell

Any help please?

Answer 1

Try:

--For Demo  
set TempPhotos to (choose folder)
set msgText to "My Test"

tell application "Finder" to set attchList to (every item of TempPhotos) as alias list

set theSender to "Me<[e-mail]>"
set recipName to "You"
set recipAddress to "[e-mail]"

tell application "Mail"

    set newmessage to make new outgoing message with properties {subject:"Important File Attachment", content:msgText & return & return, visible:false}
    tell newmessage
        set visible to false
        set sender to theSender
        make new to recipient with properties {name:recipName, address:recipAddress}
        repeat with attach in attchList
            make new attachment with properties {file name:(contents of attach)}
        end repeat

        --For Demo  
        set visible to true
    end tell
    --send newmessage
end tell