Is it possible to quickly set all spaces to the same wallpaper?

Question

It's great that Lion allows different spaces to have different wallpapers, but I have not found an easy way to get them all to use the same wallpaper.

The only way I've accomplished it so far is to either manually change the wallpaper for each space or to close all of the spaces (except the one that has the wallpaper I want) and reopen them.

Anybody have a solution to allow me to quickly set all spaces to the same wallpaper?

Answer 1

Have you got any solution?

I met with same problem so i created a quick monkey-hack solution with AppleScript:

set spacenumber to 4 -- how many spaces do you have?

-- Try to get number of spaces from System preferences
tell application "System Preferences"
    reveal anchor "shortcutsTab" of pane id "com.apple.preference.keyboard"
    tell application "System Events" to tell window "Keyboard" of process "System Preferences"
        set spacenumber to count (UI elements of rows of outline 1 of scroll area 2 of splitter group 1 of tab group 1 whose name begins with "Switch to Desktop")
    end tell
    quit
end tell

tell application "System Events"
    set _desktops to every desktop
    if (count of _desktops) > 1 then
        -- if you have multiple displat (eg: external monitor) ask which
        display dialog "Choose your screen." buttons (get display name of every desktop) default button 1
        set _display to the button returned of the result
    else
        -- else set the one display as selected
        set _display to display name of the first desktop
    end if

    set new_file to choose file with prompt "Choose an image."
    repeat with i from 0 to (spacenumber - 1)
        delay 1
        tell (every desktop whose display name is _display) to set picture to new_file as alias
        tell process "WindowServer" to key code {124} using control down -- Go to the next space
    end repeat
end tell

It's good for me now.

Update: number of spaces getter added from: https://discussions.apple.com/thread/3824777?start=0&tstart=0