Executing multiple commands over serial port with PuTTY with a .bat file with a delay between individual commands

Question

send.bat:

plink -load test < commands.txt

(test is a saved session in putty)

commands.txt

echo set_zero
timeout /t 3 /nobreak >nul 2>&1
pause >nul 2>&1
echo set_a 65535
pause >nul 2>&1
timeout /t 3 /nobreak >nul 2>&1
echo set_a 0
timeout /t 3 /nobreak >nul 2>&1
pause >nul 2>&1

When I run the send.bat, it can open putty seccessfully, but it can't input the commands which I write in the commands.txt.

I put these files in the same directory.

Answer 1

Your commands.txt file is just a mess.

I assume you want to send set_zero command, not echo set_zero command, so put set_zero to the file, not echo set_zero.

Though if you need to pause between the commands, a simple input redirection won't help, as you cannot use timeout command then. You want to execute timeout command locally, while you are sending it to the serial port. Your code is actually correct, had you used it as a script that generates an input for the plink. But for that, you need to use | not <.

This might do what you want:

(
    echo set_zero
    timeout /t 3 /nobreak >nul 2>&1
    pause >nul 2>&1
    echo set_a 65535
    pause >nul 2>&1
    timeout /t 3 /nobreak >nul 2>&1
    echo set_a 0
    timeout /t 3 /nobreak >nul 2>&1
    pause >nul 2>&1
) | plink -load test

Though, you might want to move pause only after plink:

(
    ...
    echo set_a 0
    timeout /t 3 /nobreak >nul 2>&1
) | plink -load test

pause >nul 2>&1

---

Alternativelly, as @Appleodity already suggested, rename commands.txt to commands.bat and use it like:

commands.bat | plink -load test

Again, maybe like this (after moving pause from commands.bat):

commands.bat | plink -load test

pause >nul 2>&1

Answer 2

According to documentation the correct usage is:

plink -load test -m commands.txt

-m = Read remote commands from a file.

https://www.ssh.com/ssh/putty/putty-manuals/0.68/Chapter7.html#plink-usage

Although, I’m questioning what these commands are being used for. It almost looks like the contents of the commands.txt file is another batch file and that you possibly expect that file to execute and the output to be fed to the serial port.

That is not how it works. The literal contents of commands.txt is being sent to the serial port, possibly resulting in all the invalid command errors.

If you want to execute the contents of commands.txt and send the output to the serial port you should rename commands.txt to commands.bat and pipe the output to plink using the following command: commands.bat | plink -load test