How do people manage their inventory of servers?

Question

I want to know different kinds of practices that people are using to manage inventory of servers. What I mean by inventory of servers is basically database that tracks basic information of servers such as hostname, OS type, management ip address.

A Few solutions that I can think

• Spreadsheet
• Microsoft Access

What are other solutions? What is the pro and con of these solutions?

Answer 1

It's very simple, use a software that can do that for you, from my experience on the matter, I've used GLPI, it got all the details you might need and more.

You can enter all the details about the server for example RAM, CPU, DISK ect. and add a reference id to it, what network configuration it has, who uses that server.

You can create users accounts to alert if something is wrong with their computer by submitting a support ticket, the admin will notified by email so he can answer right away or fix the problem. and you will have all the history of the problems related to the computer.

GLPI is free open source software, it has a simple web interface that makes it easy even for non technical to use it.

Answer 2

I've used small databases or even csv files, with front-end interfaces added as required. For instance, a few tables in a MySQL database with some python or php code in front to provide a user-friendly interface for searches and modifications.

Of course this all requires an admin who is comfortable with these tools, but it means the rest of the user-base does not have to a) know the tools, b) have direct access to the data store, or c) look at the data the same way you do. You can create read-only views, add authentication, allow for remote access to the data, etc. Or you can do none of that, and just have a single csv file for one person to maintain. A database is better because you can add fields when you need them without drastic changes to the interface code.

Answer 3

Please try using the following visual basic script on the server and pull out the information such as Hostname, Make, Model, Biosversion, Operating System, Serial Number, CPU, Memory and Disk drives in a .csv file. Copy the code and save it as .vbs file. All you need to do is, modify the 6th and 7th lines with the respective paths. The text file must have the hostname or FQDN name of the server where it is going to be executed.

Hope this helps.

Option Explicit

Const wbemFlagReturnImmediately = &h10
Const wbemFlagForwardOnly = &h20

Const PATH_TO_INPUT = "D:\MachineName.txt"
Const PATH_TO_OUTPUT = "D:\MachineInventory.csv"

Dim fso
Set fso = WScript.CreateObject("Scripting.FileSystemObject")

Dim shl
Set shl = WScript.CreateObject("WScript.Shell")

Dim input
Set input = fso.OpenTextFile(PATH_TO_INPUT)

Dim output
Set output = fso.CreateTextFile(PATH_TO_OUTPUT, True)

output.WriteLine "Hostname,Serial Number,Make,Model,BIOS Version,Operating System,CPU,Memory (MB),Disk Drives"

Dim wmiService
Dim wmiResults

Dim hostname
Dim make
Dim model
Dim biosversion
Dim operatingSystem
Dim serialNumber
Dim cpu
Dim memory
Dim drives

Dim line
Dim exec
Dim pingResults 
While Not input.AtEndOfStream
    line = input.ReadLine
    hostname = ""
    make = ""
    model = ""
    biosversion = ""
    operatingSystem = ""
    serialNumber = ""
    cpu = ""
    memory = ""
    drives = ""

    Set exec = shl.Exec("ping -n 2 -w 1000 " & line)
    pingResults = LCase(exec.StdOut.ReadAll)

    If InStr(pingResults, "reply from") Then
        On Error Resume Next

        Set wmiService = GetObject("winmgmts:\\" & line & "\root\CIMV2")

        If Not Err.Number = 0 Then
            output.WriteLine line & ",Error: " & Err.Description
            WScript.Echo line & ",Error: " & Err.Description
            On Error GoTo 0
        Else
            On Error GoTo 0
            hostname = line

            Set wmiResults = wmiService.ExecQuery("SELECT * FROM Win32_BIOS", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly)

            Dim item
            For Each item In wmiResults
                serialNumber = Trim(item.SerialNumber)
                biosversion = Trim(item.SMBIOSBIOSVersion)        
            Next

            Set wmiResults = wmiService.ExecQuery("SELECT * FROM Win32_ComputerSystem", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly)

            For Each item In wmiResults
                make = Trim(item.Manufacturer)
                model = Trim(item.Model)
            Next

            Set wmiResults = wmiService.ExecQuery("SELECT * FROM Win32_OperatingSystem", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly)

            For Each item In wmiResults
                operatingSystem = Trim(item.Name)
                operatingSystem = Split(operatingSystem, "|")(0)
                memory = Round(Trim(item.TotalVisibleMemorySize) / 1024, 2)
            Next

            Set wmiResults = wmiService.ExecQuery("SELECT * FROM Win32_Processor", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly)

            For Each item In wmiResults
                cpu = Trim(item.Name)
            Next

            Set wmiResults = wmiService.ExecQuery("SELECT * FROM Win32_LogicalDisk WHERE DriveType=3", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly)

            For Each item In wmiResults
                drives = drives & Trim(item.DeviceID) & "" & Round(Trim(item.Size) / (1024^2), 2) & ";  "
            Next

            output.WriteLine hostname & "," & serialNumber & "," & make & "," & model & "," & biosversion & "," & operatingSystem & "," & cpu & "," & memory & "," & drives
        End If
    Else
        output.WriteLine line & ",No Response"
        WScript.Echo line & ",No Response"
    End If
Wend 

output.Close
input.Close

Set wmiService = Nothing
Set wmiresults = Nothing