Windows 8.1 batch checking if computer is part of a workgroup and changing if necessary

Question

I've got SYSTEMINFO | FIND /I "DOMAIN:" which displays if it's part of a Domain or Workgroup. But I'm trying to figure out how to take the result of that and if it's anything other than Company.LLC to goto :JoinWorkgroup. I would imagine it should look something like this:

IF SYSTEMINFO | FIND /I "DOMAIN:" NOT = "Company.LLC" THEN GOTO :JoinWorkgroup
IF SYSTEMINFO | FIND /I "DOMAIN:" = "Company.LLC" THEN GOTO :NextVerification

I can get IF NOT EXIST to work with directories, but can't figure out how to tie it into results of prompt utilities.

Answer 1

For the first look, launch next command from command line:

for /F "tokens=1*" %G in ('SYSTEMINFO ^| FIND /I "DOMAIN:"') do @echo %G %H

For use in a batch script double the percent sign %: change %G to %%G and %H to %%H. Then an applicable code snippet in your batch script could look as follows (retain line spacing, please):

set "sDomain=WORKGROUP"
for /F "tokens=1*" %%G in ('SYSTEMINFO ^| FIND /I "DOMAIN:"') do set "sDomain=%%~H"
IF "%sDomain%"=="Company.LLC" (
    GOTO :NextVerification 
) ELSE (
    GOTO :JoinWorkgroup
)

or, if you would prefer a solution without any auxiliary variable:

for /F "tokens=1*" %%G in ('SYSTEMINFO ^| FIND /I "DOMAIN:"') do ( 
  IF "%%~H"=="Company.LLC" (
      GOTO :NextVerification 
  ) ELSE (
      GOTO :JoinWorkgroup
  )
)

Edit (although accepted): use %%~H with the ~ argument modifier to remove surrounding quotes (") if any.

Resource:

• FOR /F Loop command: against the results of another command
• structured IF ... ( command ) ELSE ( command ) Conditionally perform a command