Windows: Copy and Rename a file in a single step? Shortcut?

Question

I am tired of these steps when copying and renaming a file (Windows Explorer):

1. CTRL+C
2. CTRL+V
3. Navigation keys
4. F2

Is there no feature or shortcut in Windows 7 that a file gets copied and is in rename-mode immediately?

Maybe this is a sophisticated question, but doing this 50 times per day would save at least 50 * 2 keyboard strokes.

PS: I know you can do it using the CMD copy "file1.txt" "file2.txt", but I'd like to do it directly in Windows Explorer.

Answer 1

 ; Press F1 in Explorer to copy and manually rename the copy of the selected file
 ; - If the size of the selected is less 50 MB, directly in the explorer
 ; - otherwise using an input box (because the copying process takes more time) 

#If WinActive("ahk_class CabinetWClass")

    $F1::
    ClipSaved := ClipboardAll 
    clipboard := "" 
    Send, ^c 
    ClipWait, 2
    if (!ErrorLevel)
    {
        SplitPath, clipboard,, dir, ext, NameNoExt
        If (ext = "")
        {
            MsgBox, No file selected
            clipboard := ClipSaved
            return
        }
        FileGetSize, size, %clipboard%, M
        If (size < 50)
        {
            Sleep, 100
            Send, ^v
            Sleep, 500
            ; Send, {F2} ; or
            SendInput, {F2}%NameNoExt% ; if you want to remove " - Copy"
        }
        else
        {
           InputBox, UserInput, Filename, Enter a name for the file,, 350, 120,,,,, %NameNoExt%
            if (!ErrorLevel)    
                FileCopy, %clipboard%, %dir%\%UserInput%.%ext%, 1  
        }
    }
    else
        MsgBox, No file selected
    Sleep, 300
    clipboard := ClipSaved
    return

#If

Answer 2

I think your best path is writing some script that does what you want, then put it in the registry so that it appears when you right click -> open with on the file. The script would take your file as a parameter and then copy and rename as you wish (especially if you only want to rename as in the example, with number suffix).

And if you're looking for keyboard only, you can place a shortcut to your script on the desktop, and in the shortcut properties assign it a keyboard shortcut.

If you need to give a specific name to the file (i.e. not just an auto-suffix) you can always pop an input box of your own from the script - it's easy in most languages.

Bottom line, if you can code it, it can be done... If not, it could be a good context to take your first coding steps!