InDesign Links: Paths conflict between Mac and PC

Question

My company has used InDesign on Windows for years. When they make "Links", they are pointed to a network drive, so the file path starts with a drive letter, e.g. "N:...". We recently got iMacs, and the Links don't work with them since Mac paths don't start with drive letters.

We could update all the Links manually, but this is nearly impossible because their are thousands of files. Additionally, we still have Windows users, so changing the links would cause them to break on those machines. I don't know if it's possible to programmatically update the Links, but even if it were, they would have to be changed to something that works on both PC and Mac.

From what I can tell, it's not wise to use network drives like we have been, but I'm not sure about the alternatives.

Is there a quick fix? If not, what steps do we need to take to fix this?

Answer 1

Adobe's solution is for you to use Adobe Bridge. This question at Stack Exchange/Graphic Design has a good discussion of the problem.

When confronted with this "PC links" problem, Mac users at a prepress company would run the following Applescript to relink their file. Perhaps you will find it helpful.

global foundPaths, foundPathNames
set foundPathNames to {}
set foundPaths to {}
set missedLinks to "" -- name of links not found
tell application "Adobe InDesign CS5"
    activate
    -- choose pic folder
    set folderpath to (choose folder with prompt "Choose folder containing pictures:") as Unicode text
    tell document 1
        set missingLinks to every link whose status is link missing
        if missingLinks is not {} then
            set missingLinkNames to name of every link whose status is link missing
            set linkcount to count of items of missingLinkNames
            -- search for file recursively
            my checkforfile(folderpath, missingLinkNames, linkcount)
            set foundCount to count of items of foundPathNames
            -- see if file was found, and relink if so
            repeat with i from 1 to linkcount
                repeat with j from 1 to foundCount
                    if contents of item j of foundPathNames = contents of item i of missingLinkNames then
                        relink item i of missingLinks to alias (item j of foundPaths)
                        exit repeat
                    else if j = foundCount then
                        set missedLinks to missedLinks & (item i of missingLinkNames) & ", "
                    end if
                end repeat
            end repeat
            try -- in case there aren't any
                update (every link whose status is link out of date)
            end try
            if missedLinks = "" then
                display dialog "All links updated."
            else
                display dialog "The following links weren't found: " & return & (text 1 thru -3 of missedLinks)
            end if
        else
            display dialog "No links missing."
        end if
    end tell
end tell

on checkforfile(folderpath, fileNames, n)
    set theList to list folder file folderpath without invisibles
    repeat with anItem in theList
        set thePath to alias (folderpath & anItem) as Unicode text
        if thePath ends with ":" then
            set searchResult to my checkforfile(thePath, fileNames, n)
            if searchResult is false then
                return false
            end if
        else if contents of anItem is in fileNames then
            set end of foundPathNames to contents of anItem
            set end of foundPaths to thePath
            if (count of items of foundPaths) = n then
                return false
            end if
        end if
    end repeat
    return true
end checkforfile