reg query; Windows 7 vs Windows XP

Question

I can run the following reg query command in Windows 7 and get the following results:

command-

Reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall /s /f "EMC Avamar for Windows"

output-

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{1693DDE2-4577-46E9-AEE2-0EAFE1F2A00E}
    DisplayName    REG_SZ    EMC Avamar for Windows

Now when I run the same command in Windows XP, I get the following error:

error-

Error: Too many command-line parameters

Now I've found that with Window XP, you have to tweak the command and run it as follows:

command-

reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall /s | FIND "EMC Avamar for Windows"

The command works but I only get the following output minus the actual regkey:

output-

DisplayName REG_SZ  EMC Avamar for Windows

Like the Windows 7 command, is there a way to run the query in XP to get the key name as well?

Answer 1

Edit Use Endoro's pure batch answer instead of this one :)

If you want to use only native Windows XP commands use this:

Batch

@echo off
setlocal EnableExtensions
for /f "delims=" %%A in ('reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" /s') do (
    echo("%%~A"| find /i "EMC Avamar for Windows" && goto break
    echo("%%~A"| find /i "HKEY_" >nul && set "Last=%%A"
)
:break
echo %Last%
pause>nul
endlocal

Output

    DisplayName    REG_SZ    EMC Avamar for Windows
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{1693DDE2-4577-46E9-AEE2-0EAFE1F2A00E}

Note that the DisplayName output line is printed by the find command and the HKEY output line is printed by the echo %Last% command.

Answer 2

In XP you can use the following shell script (with GNU sed):

@echo off &SETLOCAL
SET "regkey=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
SET "search=EMC Avamar for Windows"
SET "sedkey=%regkey:\=\\%"
reg query "%regkey%" /s | sed -n "/%sedkey%/{x};/%search%/{x;p;x;p}"

sed for Windows

Answer 3

pure batch

@echo off
setlocal EnableExtensions
set "RegKey=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
set "Search=EMC Avamar for Windows"

for /f "tokens=1* delims=[]" %%A in ('reg query "%RegKey%" /s ^| find /i /n "%Search%"') do (
    set "ValuePos=%%A"
    set "Value=%%B"
)

if defined ValuePos for /f "tokens=1* delims=[]" %%A in ('reg query "%RegKey%" /s ^| find /i /n "%RegKey%"') do (
    if %ValuePos% gtr %%A SET "Key=%%B"
)

echo(%Key%
echo(%Value%