Remove "Main executable module" Icons in System Tray on Windows 10 Professional x64

Question

I have these two icons showing up in my system tray. I have Win10 Pro x64. Why are they there? How can I get rid of them, aside from simply not showing them?

Answer 1

The simplest solution to clear the binary data IconStreams and PastIconsStream located within HKEY_CURRENT_USER\SOFTWARE\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify

1. Run the .bat script below
2. Close and save anything that you are working on before proceeding. The next steps will involve killing explorer and restarting the PC.
3. Run the .bat file.
4. If prompted, click/tap on Run to approve. If you like, you can unblock the .bat file to no longer get the Run (Open File - Security Warning) prompt.
5. Follow the instructions in the command prompt to reset your notification area icons. If you do not restart the PC now, you will need to later to finish resetting your notification area icons. (see screenshots below)

Source: How to Reset Notification Area Icons in Windows 10

Reset_Notification_Area_Icons_Cache

:: Created by: Shawn Brink
:: http://www.tenforums.com
:: Tutorial: http://www.tenforums.com/tutorials/5662-notification-area-icons-reset-windows-10-a.html


@echo off

set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream


echo.
echo The Explorer process must be temporarily killed before deleting your notification area icons cache. 
echo.
echo Please SAVE ALL OPEN WORK before continuing.
echo.
pause


echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
echo Registry key "IconStreams" already deleted.
echo.

:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto restart

:IconStreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream

:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"


:restart
echo.
echo.
echo You will need to restart the PC to finish resetting your notification area icons.
echo.
CHOICE /C:YN /M "Do you want to restart the PC now?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes


:no
echo.
echo.
echo Restarting explorer.... 
echo.
echo Please remember to restart the PC later to finish resetting your notification area icons.
echo.
start explorer.exe
pause
exit /B

:yes
shutdown /r /f /t 00