Extract One letter and three numbers from .txt files using Notepad++

Question

I would like to extract from many .txt files a certain data in Notepad++. It has a lot of data in one file, but I only need specific...

This is what looks like in a file:

©Q Ńü Vý 8 ź) €G' €\Y € €w) €â` € K¶ K¶}Ąg† ‚Z™y ë( \Y
SCfsfgh4GHGH1+ €‡Ş € € €?° €¸ € k k € ‡Ş b | -A233 ™ž B¤ ˙˙˙˙˙˙˙˙˙˙˙˙ ’ ˙ rtSdpeRB ˙ GÚS)PS 3: TRANSMIT FILE created by modeller version 1101322 SCH_900000_9008 @Ź@

And I need to extract this:

A233

TIP: There is a space before - sign ( -A233) Also, every file has different numbers next to letter A

In the original file looks like this (a lot of spaces are extracted via copy-paste):

Answer 1

You can use Replace (ctrl-h) with the following:

Find what: .*? -(A\d+)

Replace with: \1\n

Check the box for ". matches newline" if they exist in your files

Explanation:

.*? - - Finds everything up to " -", including any newlines

(A\d+) - Defines a capture group that finds A followed immediately by 1 or more numbers

\1\n - Replaces matches with the captured number and a newline for separating them

You can swap out the \n with the delimiter of your choice

Note that this will not delete any text after the last match, but since you're already in a text editor deleting it is trivial.

Answer 2

Since you have many .txt files, it makes sense to do a simple automation instead of extracting the values from each file manually. I suggest to use the WSH VBScript below:

strRes = ""
For Each strPath In WScript.Arguments
    With CreateObject("Scripting.FileSystemObject")
        If .FileExists(strPath) Then
            strRes = strRes & .GetFileName(strPath) & vbCrLf
            strCont = LoadTextFromFile(strPath, "us-ascii")
            With CreateObject("VBScript.RegExp")
                .Global = True
                .MultiLine = True
                .IgnoreCase = False
                .Pattern = "-A(\d{3})"
                Set objMatches = .Execute(strCont)
                For Each objMatch In objMatches
                    strRes = strRes & objMatch.SubMatches(0) & vbCrLf
                Next
            End With
        End If
    End With
Next
ShowInNotepad strRes

Function LoadTextFromFile(strPath, strCharset)
    With CreateObject("ADODB.Stream")
        .Type = 1 ' TypeBinary
        .Open
        .LoadFromFile strPath
        .Position = 0
        .Type = 2 ' adTypeText
        .Charset = strCharset
        LoadTextFromFile = .ReadText
        .Close
    End With
End Function

Sub ShowInNotepad(strToFile)
    Dim strTempPath
    With CreateObject("Scripting.FileSystemObject")
        strTempPath = CreateObject("WScript.Shell").ExpandEnvironmentStrings("%TEMP%") & "\" & .GetTempName
        With .CreateTextFile(strTempPath, True, True)
            .WriteLine strToFile
            .Close
        End With
        CreateObject("WScript.Shell").Run "notepad.exe " & strTempPath, 1, True
        .DeleteFile (strTempPath)
    End With
End Sub

Just paste this code to the notepad, save as text file, and manually replace .txt file extension with .vbs. Then all that you need is select your text files in explorer window, and drag and drop them onto the script.

For the files you have shared I has the output as follows:

30_SCH51BQ139.txt

036

30_SCH51BQ141.txt

038

30_SCH51BQ144.txt

040

30_SCH51BQ147.txt

043