Disable/enable lan-device by batchfile: If comparisons not working

Question

I have created this .bat-file which is invoked by clicking on the proper shortcut, which is configured properly. But the last two comparisons seem not to evaluate properly.

Here we go.

@ECHO off
SETLOCAL EnableDelayedExpansion 

SET landevcename='Imagine any name for a device'

SET landevcestatus=0
SET landevcestatusDisab=0
SET landevcestatusConn=2
SET landevcestatusT="NONE"
SET landevceidx=0

SET counter=1

ECHO Lan device to be checked is: %landevcename%

FOR /F "tokens=1" %%I IN ('wmic PATH win32_networkadapter where "Name=%landevcename%" get index')  DO ( 
        IF !counter!==2 SET /a landevceidx=%%I             

        SET /a counter+=1
     )
ECHO Index of local area connection is: %landevceidx%

SET /a counter=1
FOR /F "tokens=1" %%J IN ('wmic PATH win32_networkadapter where "Name=%landevcename%" get netconnectionstatus')  DO (       
                            IF !counter!==2 SET /a landevcestatus=%%J              

                            SET /a counter+=1
                           )

ECHO Status of local area connection is: %landevcestatus%                          

REM IF %landevcestatus%==%landevcestatusDisab% SET /a landevcestatusT=Disabled
IF %landevcestatus%==0 SET /a %landevcestatusT% "ItIsNotEnabled"

REM IF %landevcestatus%==%landevcestatusConn% SET /a landevcestatusT=Connected         
**IF %landevcestatus%==2 SET /a %landevcestatusT% "ItIsEnabled"**

ECHO Text - Status of local area connection is: %landevcestatusT%

ECHO Status of local area connection is: %landevcestatus%                          

CMD
@ECHO off

Those both:

IF %landevcestatus%==0 SET /a %landevcestatusT% "ItIsNotEnabled"

IF %landevcestatus%==2 SET /a %landevcestatusT% "ItIsEnabled"

Where could be the typo ?

Answer 1

Where could be the typo?

• You have many errors in your batch file.

• You are clearly confused about how to use set and set /a. Please read set.

• It would also be worth you reading Debugging your batch files.

• A general observation - fix your indentation (it makes debugging easier).

---

Corrections

SET landevcename='Imagine any name for a device'

Should be:

SET landevcename="Imagine any name for a device"

If you use ' then you need to escape the ' in your for command.

---

IF !counter!==2 SET /a landevceidx=%%I

Should be:

IF !counter!==2 SET landevceidx=%%I

/a is used for numeric expressions not string assignments.

---

IF !counter!==2 SET /a landevcestatus=%%J 

Should be:

IF !counter!==2 SET landevcestatus=%%J

---

SET /a counter+=1

Should be:

SET /a "counter+=1"

---

IF %landevcestatus%==0 SET /a %landevcestatusT% "ItIsNotEnabled"

Should be:

IF %landevcestatus%==0 SET landevcestatusT="ItIsNotEnabled"

---

IF %landevcestatus%==2 SET /a %landevcestatusT% "ItIsEnabled"

Should be:

IF %landevcestatus%==2 SET landevcestatusT="ItIsEnabled"

---

FOR /F "tokens=1" %%I IN ('wmic PATH win32_networkadapter where "Name=%landevcename%" get index')  DO ( 

Should be:

FOR /F "tokens=1" %%I IN ('wmic PATH win32_networkadapter where Name^=%landevcename% get index')  DO ( 

You need to escape the = using ^, and remove the "s (they are part of the variable %landevcename%).

---

Simplified batch file

You can do what you want with a single for /f command and fewer variables. You don't need an index or a counter.

Use the following batch file and set landevicename as appropriate.

LanStatus.cmd:

@echo off
setlocal 

set landevcename="Remote NDIS based Internet Sharing Device"

echo Lan device to be checked is: %landevcename%

rem skip first line
rem use findstr to strip blank lines from wmic output
for /f "usebackq skip=1 tokens=1,2" %%i IN (`wmic PATH win32_networkadapter where Name^=%landevcename% get netconnectionstatus^, index ^| findstr /r /v "^$"`)  DO (  set landevceidx=%%i
  set landevcestatus=%%j       
  )

if %landevcestatus%==2 (
  set landevcestatusT="ItIsEnabled"
  ) else (
  set landevcestatusT="ItIsNotEnabled"
  )

echo Text - Status of local area connection is: %landevcestatusT%

echo Status of local area connection is: %landevcestatus%                        

echo Index of local area connection is: %landevceidx%

endlocal

Example output:

F:\test>lanstatus
Lan device to be checked is: "Remote NDIS based Internet Sharing Device"
Text - Status of local area connection is: "ItIsEnabled"
Status of local area connection is: 2
Index of local area connection is: 17

---

Further Reading

• An A-Z Index of the Windows CMD command line - An excellent reference for all things Windows cmd line related.
• findstr - Search for strings in files.
• for /f - Loop command against the results of another command.
• if - Conditionally perform a command.
• set - Display, set, or remove CMD environment variables. Changes made with SET will remain only for the duration of the current CMD session.
• wmic - Windows Management Instrumentation Command.