How do I remove the Refresh button from the Address toolbar?

Question

I like being able to run commands straight from my Task Bar. So, I've enabled the Address toolbar on my new Windows 7 system - just like I had on my old XP system. However, the bar seems to have a mandatory minimum length (I've posted a separate question about that) that's a bit longer than I'd prefer. Additionally, a bit more horizontal space is consumed by a Refresh button at the end of it.

This Refresh button appears similar to the Go button that used to show by default in older versions. That button was easily removed by changing a registry value that doesn't seem to exist in Windows 7. Is there a similar registry hack I can use to remove the new Refresh button?

Answer 1

Like I said in your other question, there is no built-in way to modify the address bar. You will need to use a third-party program that runs in the background and modifies the address-bar's properties to adjust its length and hide the refresh button.

Unfortunately, I don't know of any such programs, nor can I find any. I have a tool I wrote myself that is similar to WinSpy++, but while both my program and WinSpy++ can be used to alter the length and hide the button manually, neither one runs in the background to detect whenever the address-bar is created and perform the modifications automatically.

One thing you could try is to use a hotkey/macro type of program that can let you set triggers to perform events, and set a trigger to be window created - address-bar... and set the event to be hide refresh button; set address-bar length=... This can probably be accomplished with AutoHotkey or AutoIt as well.

This is the AutoHotKey port of my C++ program to remove the refresh button. (It can be compiled and run in the background.)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; NoAddressBarButton.ahk (http://superuser.com/questions/444406/)
;
; This script hides the refresh button of the address-bar band of the Windows 7
; taskbar. It also extends the combo-box (edit field) to use the space of the
; refresh button.
;
;   (cl) 2012- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#NoTrayIcon                                       ;No tray icon, duh
#NoEnv                                            ;Not using environment vars
#SingleInstance Force                             ;Use only a single instance
#Persistent                                       ;Using a timer loop; keep open

SetTimer, Run, 1000                               ;Re-run the check every second

Run:
IfWinExist ahk_class Shell_TrayWnd                ;Check if taskbar exists
{
  ControlGet, tv, Visible, ,  ToolbarWindow323    ;Is refresh button visible?
  ControlGetPos, tx,ty,tw,th, ToolbarWindow323    ;Get button width
  ControlGetPos, cx,cy,cw,ch, ComboBoxEx321       ;Get combobox width
  ControlGetPos, mx,my,mw,mh, msctls_progress321  ;Get address-bar width
  if ((tv==1) || (cw<mw))                         ;If button visible
                                                  ;or resized (combobox is short)
  {
    Control, Hide,, ToolbarWindow323              ;(Re-)hide the refresh button
    ControlGetPos, cx,cy,cw,ch, ComboBoxEx321     ;Get current combobox width
    cw:=cw+tw                                     ;Add the button width
    ControlMove, ComboBoxEx321, , , %cw% ,        ;Extend combobox to include button
  }
}